您现在的位置： 主页 > 仿真实验项目 > 本次申报——2017年度示范性虚拟仿真实验教学项目 > 氮化镓发光二极管工艺制造与光电特性虚拟仿真实验项目 > 实验程序 >

氮化镓发光二极管仿真程序.in

点击数：   

##AlGaN 单量子阱GaN LED 的虚拟工艺实现部分
go athena
#非故意掺杂AlxGa1-xN缓冲层的厚度 h1 1μm≤h1≤4μm
set H1=2
#非故意掺杂AlxGa1-xN缓冲层的Al组分 x 0.2≤x≤0.7
set ALX=0.4
 
#N型AlxGa1-xN层的厚度 h2 0.2μm≤h2≤1μm
set TAL1=0.5
#N型AlxGa1-xN层的掺杂浓度 h 5×1017cm-3≤N1≤1×1019cm-3
set NAL1=2e18
 
#非故意掺杂AlyGa1-yN量子阱层的厚度 h3 2nm≤h3≤10nm
set TAL2=0.003
#非故意掺杂AlyGa1-yN量子阱层的Al组分 y 0.1≤y≤0.6
set ALY=0.3
 
#P型AlzGa1-zN层的厚度 h4 5nm≤h4≤50nm
set TAL3=0.01
#P型AlzGa1-zN层的掺杂浓度 N2 5×1016cm-3≤N2≤1×1020cm-3
set NAL3=1e20
#P型AlzGa1-zN层的Al组分 z 0.3≤z≤0.8
set ALZ=0.5
 
#P型GaN层的厚度 h5 20nm≤h5≤200nm 
set TGAN=0.08
#P型GaN层的掺杂浓度 N3 1×1017cm-3≤N3≤1×1020cm-3
set NGAN=1e20
#
#line y loc=-0.1 s=0.5
#line y loc=0.0 s=0.05
#line y loc=$TGAN s=0.001
#line y loc=$TGAN+$TAL3 s=0.0001
#line y loc=$TGAN+$TAL3+$TAL2 s=0.0001
 
#line y loc=$TGAN+$TAL3+$TAL2+0.03 s=0.001
#line y loc=$TGAN+$TAL3+$TAL2+0.03+0.2 s=0.01
#line y loc=$TGAN+$TAL3+$TAL2+0.03+$TAL1 s=0.01
 
#line y loc=$TGAN+$TAL3+$TAL2+0.03+$TAL1+$H1 s=0.5
#line y loc=5.0 s=0.2
 
line x l=0.0 s=0.2
line x l=0.15 s=0.1
line x l=1.75 s=0.1
line x l=1.85 s=0.1
line x l=1.95 s=0.1
line x l=3.45 s=0.1
line x l=3.5 s=0.2
 
line y loc=2.623 s=0.5
line y loc=5.0 s=0.5
 
init material=sapphire two.d
##
deposit material=AlGaN thickness=$H1 x.comp=$ALX
deposit material=AlGaN thickness=$TAL1 x.comp=$ALX
deposit material=AlGaN thickness=0.03 x.comp=0.4
deposit material=AlGaN thickness=$TAL2 x.comp=$ALY
deposit material=AlGaN thickness=$TAL3 x.comp=$ALZ
deposit material=GaN thickness=$TGAN
#
etch start   x=1.85 y=0.0
etch continue   x=1.85 y=$TGAN+$TAL3+$TAL2+0.03+0.2
etch continue   x=3.5  y=$TGAN+$TAL3+$TAL2+0.03+0.2
etch done   x=3.5  y=0.0
 
deposit material=Tin thickness=0.1 div=3
etch material=Tin left p1.x=1.95
etch material=Tin right p1.x=3.45
 
deposit material=nickel thickness=0.1 div=3
etch material=nickel left p1.x=0.15
etch material=nickel right p1.x=1.75
 
electrode name=anode x=0.95
electrode name=cathode x=2.5
##
structure outfile=GaN_LED.str
#############################################################
go atlas
mesh infile=GaN_LED.str scale.x=100
save outf=GaN_LED_0.str 
 
#############################################################
 
##AlGaN单量子阱GaN LED 器件光电特性仿真部分
 
go atlas
mesh infile=GaN_LED_0.str  width=477
 
region num=1 x.min=0.0 x.max=185.0 y.min=$TGAN+$TAL3+$TAL2+0.03 y.max=$TGAN+$TAL3+$TAL2+0.03+0.2 material=AlGaN x.comp=$ALX 
region num=1 x.min=0.0 x.max=350.0 y.min=$TGAN+$TAL3+$TAL2+0.03+0.2 y.max=$TGAN+$TAL3+$TAL2+0.03+$TAL1 material=AlGaN x.comp=$ALX 
region num=2 x.min=0.0 x.max=185.0 y.min=$TGAN+$TAL3+$TAL2 y.max=$TGAN+$TAL3+$TAL2+0.03 material=AlGaN x.comp=0.4
region num=3 x.min=0.0 x.max=185.0 y.min=$TGAN+$TAL3 y.max=$TGAN+$TAL3+$TAL2 material=AlGaN x.comp=$ALY qwell led well.ny=40
region num=4 x.min=0.0 x.max=185.0 y.min=$TGAN  y.max=$TGAN+$TAL3  material=AlGaN x.comp=$ALZ
region num=5 x.min=0.0 x.max=185.0 y.min=0 y.max=$TGAN material=GaN
 
# SECTION 3: DOPING
doping uniform num=1 x.min=0.0 x.max=185.0 y.min=$TGAN+$TAL3+$TAL2+0.03 y.max=$TGAN+$TAL3+$TAL2+0.03+0.2 n.type conc=$NAL1
doping uniform num=1 x.min=0.0 x.max=350.0 y.min=$TGAN+$TAL3+$TAL2+0.03+0.2 y.max=$TGAN+$TAL3+$TAL2+0.03+$TAL1 n.type conc=$NAL1
doping uniform num=4 x.min=0.0 x.max=185 y.min=$TGAN  y.max=$TGAN+$TAL3  p.type conc=$NAL3
doping uniform num=5 x.min=0.0 x.max=185.0 y.min=0 y.max=$TGAN p.type conc=$NGAN
 
#save outf=GaN_LED_1.str 
 
models polarization calc.strain polar.scale=0.15
 
material material=GaN taun0=1e-9 taup0=1e-9 copt=1.1e-8 \
         augn=1.0e-34 augp=1.0e-34
material material=AlGaN taun0=1e-9 taup0=1e-9 copt=1.1e-8 \
         augn=1.0e-34 augp=1.0e-34
#
material well.gamma0=10e-3
#
material edb=0.080 eab=0.101
#
models k.p fermi incomplete consrh auger optr print
models name=well k.p chuang spontaneous lorentz
#
mobility material=GaN mun0=300 mup0=10
mobility material=AlGaN mun0=250 mup0=5
#
output con.band val.band band.param charge polar.charge e.mobility h.mobility \
       u.srh u.radiative u.auger permi
#
solve init
#
method climit=1e-4 maxtrap=10 
#block nblockit=50
#
solve prev
#
save outf=ledex5_1.str
#
probe name="Radiative"     integrate radiative rname=well
probe name="Recombination" integrate recombination
#
log outf=ledex5.log
solve vstep=0.1 vfinal=3.5 name=anode
save outf=ledex5_3p5.str
save spectrum=ledex5_3p5.spc lmin=0.22 lmax=0.35 nsamp=100
 
solve vstep=0.1 vfinal=4.0 name=anode
save outf=ledex5_4p0.str
save spectrum=ledex5_4p0.spc lmin=0.22 lmax=0.35 nsamp=100
 
solve vstep=0.1 vfinal=5.0 name=anode
save outf=ledex5_5p0.str
save spectrum=ledex5_5p0.spc lmin=0.22 lmax=0.35 nsamp=100
 
solve vstep=0.1 vfinal=6.0 name=anode
save outf=ledex5_6p0.str
save spectrum=ledex5_6p0.spc lmin=0.22 lmax=0.35 nsamp=100
#
# V-I Curve
tonyplot ledex5.log -set ledex5_0.set
# EL Spectrum
tonyplot ledex5_5p0.spc -set ledex5_1.set
quit